Salesforce 系统管理员（验证规则）

学习目标

完成本单元后，您将能够：

  • 描述验证规则的两个用例。
  • 列出验证规则的元素。
  • 创建一个验证规则。

验证规则简介

验证规则验证用户在记录中输入的数据是否符合您指定的标准，然后才能保存。验证规则可以包含一个公式或表达式，用于评估一个或多个字段中的数据，并返回“True”或“False”值。验证规则还可以包含在用户输入基于指定的无效值时向用户显示的错误消息标准。使用这些规则有效地提高了质量数据。例如，您可以确保所有电话号码字段都包含指定的格式，或者应用于特定产品的折扣不会超过定义的百分比。

定义验证规则

您可以为对象，字段，活动成员或案例里程碑创建验证规则。在这些步骤中，我们将创建一个验证规则，当用户尝试使用长度不正确的帐号保存帐号时触发。

创建一个验证规则

  1. 从Setup,转到对象管理器，然后Account.
  2. 在左侧边栏中，点击 Validation Rules.
  3. 点击 New.
  4. 为您的验证规则输入以下属性：
    1. 规则名称： Account_Number_8_Characters
    2. 错误条件公式： 
      LEN( AccountNumber) != 8
  5. 错误消息：帐号必须是8个字符。
  6. 要检查公式中的错误，请单击“检查语法”。
  7. 点击 Save 完成。
以下是当用户在字段中输入不正确的电话号码格式时验证规则的错误消息的显示方式。

A filled out validation rule, including a related error message.

验证规则示例

以下是一些您可以自行尝试的验证规则示例：

帐号是数字

字段 值
说明: 验证帐号是否为数字，如果不是空白。
公式: 
	AND(
   NOT(ISBLANK(AccountNumber)),
   NOT(ISNUMBER(AccountNumber))
)
错误消息： Account Number is not numeric.
错误位置： Account Number

日期必须在当年

字段 值
说明: 验证自定义日期字段是否包含当前年份的日期。
公式: YEAR( My_Date__c ) <> YEAR ( TODAY() )
错误消息: 日期必须在当年。
错误位置: My Date

字范围验证

字段 值
说明: 验证两个自定义字段之间的范围Salary Min和Salary Max不大于$ 20,000。
公式: 
(Salary_Max__c - Salary_Min__c) > 20000
错误消息： 薪水范围必须在$ 20,000以内。调整薪资最大值或薪资最小值。
错误地点: Salary Max

网站扩展

字段 值
说明: 验证名为“网站”的自定义字段，以确保其最后四个字符位于明确的有效网站扩展集中。
公式: 
AND(
   RIGHT( Web_Site__c, 4) <> ".COM",
   RIGHT( Web_Site__c, 4) <> ".com",
   RIGHT( Web_Site__c, 4) <> ".ORG",
   RIGHT( Web_Site__c, 4) <> ".org",
   RIGHT( Web_Site__c, 4) <> ".NET",
   RIGHT( Web_Site__c, 4) <> ".net"
 )
错误消息： 网站必须具有.com，.org或.net的扩展名。
错误位置: Web Site

有效结算国家/地区

字段 值
说明: 验证帐户结算国家/地区是有效的ISO 3166双字母代码。
公式: 
OR(
LEN(BillingCountry) = 1,
NOT(
CONTAINS(
"AF:AX:AL:DZ:AS:AD:AO:AI:AQ:AG:AR:AM:" &
"AW:AU:AZ:BS:BH:BD:BB:BY:BE:BZ:BJ:BM:BT:BO:" &
"BA:BW:BV:BR:IO:BN:BG:BF:BI:KH:CM:CA:CV:KY:" &
"CF:TD:CL:CN:CX:CC:CO:KM:CG:CD:CK:CR:CI:HR:" &
"CU:CY:CZ:DK:DJ:DM:DO:EC:EG:SV:GQ:ER:EE:ET:FK:" &
"FO:FJ:FI:FR:GF:PF:TF:GA:GM:GE:DE:GH:GI:GR:GL:" &
"GD:GP:GU:GT:GG:GN:GW:GY:HT:HM:VA:HN:HK:HU:" &
"IS:IN:ID:IR:IQ:IE:IM:IL:IT:JM:JP:JE:JO:KZ:KE:KI:" &
"KP:KR:KW:KG:LA:LV:LB:LS:LR:LY:LI:LT:LU:MO:MK:" &
"MG:MW:MY:MV:ML:MT:MH:MQ:MR:MU:YT:MX:FM:MD:MC:" &
"MC:MN:ME:MS:MA:MZ:MM:MA:NR:NP:NL:AN:NC:NZ:NI:" &
"NE:NG:NU:NF:MP:NO:OM:PK:PW:PS:PA:PG:PY:PE:PH:" &
"PN:PL:PT:PR:QA:RE:RO:RU:RW:SH:KN:LC:PM:VC:WS:" &
"SM:ST:SA:SN:RS:SC:SL:SG:SK:SI:SB:SO:ZA:GS:ES:" &
"LK:SD:SR:SJ:SZ:SE:CH:SY:TW:TJ:TZ:TH:TL:TG:TK:" &
"TO:TT:TN:TR:TM:TC:TV:UG:UA:AE:GB:US:UM:UY:UZ:" &
"VU:VE:VN:VG:VI:WF:EH:YE:ZM:ZW",
BillingCountry)))
错误消息： 需要有效的双字母国家代码。
错误位置： Billing Country