分类： Apex Trigger

在记录集上运行

我们先来看触发器中最基本的批量设计概念。批量触发器在触发器上下文中的所有sObjects上运行。通常情况下，如果触发触发器的操作来自用户界面，触发器将在一条记录上运行。但是，如果操作的起源是批量DML或API，则触发器将在记录集上运行，而不是一个记录。例如，当您通过API导入多条记录时，触发器将在整个记录集上进行操作。因此，一个良好的编程习惯就是始终假设触发器在一系列记录上运行，以便在任何情况下都能正常工作。

以下触发器假设只有一条记录导致触发器触发。在同一事务中插入多个记录时，此触发器不能在完整的记录集上工作。下一个示例中显示了一个批量版本。

trigger MyTriggerNotBulk on Account(before insert) {
    Account a = Trigger.New[0];
    a.Description = 'New description';
}

trigger MyTriggerBulk on Account(before insert) {
    for(Account a : Trigger.New) {
        a.Description = 'New description';
    }
}

SOQL查询可以是强大的。您可以检索相关记录，并在一个查询中检查多个条件的组合。通过使用SOQL功能，您可以编写更少的代码并减少对数据库的查询。减少数据库查询有助于避免遇到查询限制，即同步Apex的100个SOQL查询或异步Apex的200个查询限制。

以下触发器显示要避免的SOQL查询模式。这个例子在for循环中创建一个SOQL查询，以获取每个客户的相关机会，每个客户在Trigger.New中为每个Account sObject运行一次。如果您拥有大量客户，for循环中的SOQL查询可能导致太多的SOQL查询。下一个例子显示了推荐的方法。

trigger SoqlTriggerNotBulk on Account(after update) {   
    for(Account a : Trigger.New) {
        // 获取每个客户的子记录
        // 对于每个客户运行一次的SOQL查询效率低下！
        Opportunity[] opps = [SELECT Id,Name,CloseDate 
                             FROM Opportunity WHERE AccountId=:a.Id];
        
        // 做一些其他处理
    }
}

• SOQL查询使用内部查询（SELECT Id FROM Opportunities）来获取相关的客户机会。
• SOQL查询通过使用IN子句并绑定WHERE子句中的Trigger.New变量（WHERE Id IN：Trigger.New）连接到触发器上下文记录。这个WHERE条件将客户过滤为仅触发此触发器的记录。

将查询中的两部分结合起来，就可以在一次调用中得到我们想要的记录：这个客户将触发每个客户的相关机会。

获取记录及其相关记录之后，for循环通过使用集合变量（本例中为acctsWithOpps）来迭代感兴趣的记录。 collection变量保存SOQL查询的结果。这样，for循环只能遍历我们想要操作的记录。由于相关的记录已经被获得，所以在循环内不需要进一步的查询来获得这些记录。

trigger SoqlTriggerBulk on Account(after update) {  
    // 执行一次SOQL查询。
    // 获取客户及其相关机会。
    List<Account> acctsWithOpps = 
        [SELECT Id,(SELECT Id,Name,CloseDate FROM Opportunities) 
         FROM Account WHERE Id IN :Trigger.New];
  
    // 遍历返回的客户 
    for(Account a : acctsWithOpps) { 
        Opportunity[] relatedOpps = a.Opportunities;  
        // 做一些其他处理
    }
}

trigger SoqlTriggerBulk on Account(after update) {  
    // 执行一次SOQL查询。
    // 获取这个触发器中客户的相关机会。
    List<Opportunity> relatedOpps = [SELECT Id,Name,CloseDate FROM Opportunity
        WHERE AccountId IN :Trigger.New];
  
    // 遍历相关的机会 
    for(Opportunity opp : relatedOpps) { 
        // 做一些其他处理
    }
}

trigger SoqlTriggerBulk on Account(after update) {  
    // 执行一次SOQL查询。  
    // 在此触发器中获取客户的相关机会，
    // 并遍历这些记录。
    for(Opportunity opp : [SELECT Id,Name,CloseDate FROM Opportunity
        WHERE AccountId IN :Trigger.New]) {
  
        // 做一些其他处理
    }
}

执行批量DML

在触发器或类中执行DML调用时，尽可能在一组sObject上执行DML调用。在每个sObject上执行DML单独使用资源效率低下。 Apex运行时允许在一个事务中多达150个DML调用。

该触发器在for循环中执行更新调用，该循环遍历相关的机会。如果满足某些条件，则触发器更新机会描述。在这个例子中，更新语句对于每个机会被低效地调用一次。如果批量客户更新操作触发了该触发器，则可能有多个客户。如果每个客户有一两个机会，我们可以很容易地结束150个机会。 DML语句限制是150个调用。

trigger DmlTriggerNotBulk on Account(after update) {   
    // 获取这个触发器中客户的相关机会。
    List<Opportunity> relatedOpps = [SELECT Id,Name,Probability FROM Opportunity
        WHERE AccountId IN :Trigger.New];          

    // 遍历相关的机会
    for(Opportunity opp : relatedOpps) {      
        // 当概率大于50％但小于100％时更新描述
        if ((opp.Probability >= 50) && (opp.Probability < 100)) {
            opp.Description = 'New description for opportunity.';
            // 为每个机会更新一次 - 效率不高！
            update opp;
        }
    }    
}

trigger DmlTriggerBulk on Account(after update) {   
    // 获取这个触发器中客户的相关机会。 
    List<Opportunity> relatedOpps = [SELECT Id,Name,Probability FROM Opportunity
        WHERE AccountId IN :Trigger.New];
          
    List<Opportunity> oppsToUpdate = new List<Opportunity>();

    // Iterate over the related opportunities
    for(Opportunity opp : relatedOpps) {      
        // 当概率大于50％但小于100％时更新描述
        if ((opp.Probability >= 50) && (opp.Probability < 100)) {
            opp.Description = 'New description for opportunity.';
            oppsToUpdate.add(opp);
        }
    }
    
    // 在集合上执行DML
    update oppsToUpdate;
}

批量设计模式的实际操作：获取相关记录的触发器示例

让我们通过编写一个访问客户相关机会的触发器来应用您所学习的设计模式。修改AddRelatedRecord触发器的前一单元的触发器示例。 AddRelatedRecord触发器批量操作，但效率不如它可能是因为它遍历所有Trigger.New sObject记录。下一个示例修改SOQL查询以仅获取感兴趣的记录，然后遍历这些记录。如果你还没有创建这个触发器，不要担心，你可以在本节中创建它。

让我们从AddRelatedRecord触发器的要求开始。客户被插入或更新后触发器触发。触发器为每个没有机会的客户添加一个默认机会。要解决的第一个问题是弄清楚如何获得孩子的机会记录。因为这个触发器是一个after触发器，我们可以从数据库中查询受影响的记录。他们已经被触发后触发的时间。让我们编写一个SOQL查询，返回这个触发器中没有相关机会的所有账号。

[SELECT Id,Name FROM Account WHERE Id IN :Trigger.New AND
                                             Id NOT IN (SELECT AccountId FROM Opportunity)]

for(Account a : [SELECT Id,Name FROM Account WHERE Id IN :Trigger.New AND
                                         Id NOT IN (SELECT AccountId FROM Opportunity)]){
}

1. 如果您已经在上一个单元中创建了AddRelatedRecord触发器，请通过用以下触发器替换其内容来修改触发器。否则，请使用开发者控制台添加以下触发器，并为触发器名称输入AddRelatedRecord。

   trigger AddRelatedRecord on Account(after insert, after update) {
       List<Opportunity> oppList = new List<Opportunity>();
       
       //为每个客户添加一个机会，如果它还没有。
       // 遍历此触发器中没有机会的客户。
       for (Account a : [SELECT Id,Name FROM Account
                        WHERE Id IN :Trigger.New AND
                        Id NOT IN (SELECT AccountId FROM Opportunity)]) {
           // 为此客户添加一个默认机会
           oppList.add(new Opportunity(Name=a.Name + ' Opportunity',
                                      StageName='Prospecting',
                                      CloseDate=System.today().addMonths(1),
                                      AccountId=a.Id)); 
       }
       
       if (oppList.size() > 0) {
           insert oppList;
       }
   }

2. 要测试触发器，请在Salesforce用户界面中创建一个客户，并将其命名为“Lions＆Cats”。
3. 在客户页面的机会相关列表中，找到新的机会狮子会＆猫。触发器自动添加了机会！

Trigger 语法

trigger TriggerName on ObjectName (trigger_events) {
   code_block
}

触发器的类型

有两种类型的触发器。

• 触发器在保存到数据库之前用于更新或验证记录值之前。
• 使用触发器访问由系统设置的字段值（例如记录的Id或LastModifiedDate字段），并影响其他记录中的更改。触发后触发器的记录是只读的。

使用上下文变量

要访问导致触发器触发的记录，请使用上下文变量。例如，Trigger.New包含插入或更新触发器中插入的所有记录。 Trigger.Old在更新触发器中更新之前提供旧版本的sObjects，或在删除触发器中删除sObjects的列表。当插入一个记录时，或者通过API或Apex批量插入大量记录时，触发器可以触发。因此，上下文变量（如Trigger.New）只能包含一条记录或多条记录。您可以遍历Trigger.New来获取每个单独的sObject。

这个例子是HelloWorldTrigger示例触发器的修改版本。它遍历for循环中的每个帐户并更新每个帐户的说明字段。

trigger HelloWorldTrigger on Account (before insert) {
    for(Account a : Trigger.New) {
        a.Description = 'New description';
    }   
}

trigger ContextExampleTrigger on Account (before insert, after insert, after delete) {
    if (Trigger.isInsert) {
        if (Trigger.isBefore) {
            // Process before insert
        } else if (Trigger.isAfter) {
            // Process after insert
        }        
    }
    else if (Trigger.isDelete) {
        // Process after delete
    }
}

触发上下文变量

下表是可用于触发器的所有上下文变量的综合列表。

从触发器调用类方法

您可以通过触发器调用公用事业方法。调用其他类的方法可以重用代码，减少触发器的大小，并且可以提高Apex代码的维护。它也允许你使用面向对象的编程。

以下示例触发器显示如何从触发器调用静态方法。如果由于插入事件触发了该触发器，则此示例将在EmailManager类上调用静态sendMail（）方法。此实用程序方法向指定的收件人发送电子邮件，并包含插入的联系人记录数。

1. 在开发者控制台中，点击 File | New | Apex Trigger.
2. 输入ExampleTrigger作为触发器名称，然后选择Contact作为sObject。点击 Submit.
3. 将默认代码替换为以下内容，然后将sendMail（）中的电子邮件地址占位符文本修改为您的电子邮件地址。

   trigger ExampleTrigger on Contact (after insert, after delete) {
       if (Trigger.isInsert) {
           Integer recordCount = Trigger.New.size();
           // 从另一个类调用实用程序方法
           EmailManager.sendMail('Your email address', 'Trailhead Trigger Tutorial', 
                       recordCount + ' contact(s) were inserted.');
       }
       else if (Trigger.isDelete) {
           // 删除后的处理
       }
   }

4. 要保存，请按Ctrl + S。
5. 要测试触发器，请创建一个联系人。
   1. 单击 Debug | Open Execute Anonymous Window.
   2. 在新窗口中，添加以下内容，然后单击 Execute.

      Contact c = new Contact(LastName='Test Contact');
      insert c;

6. 在调试日志中，检查触发器是否被触发。在日志末尾，找到实用程序方法编写的调试消息： DEBUG|Email sent successfully
7. 现在检查您是否收到一封电子邮件，其中正文 1 contact(s) were inserted.

   使用新的触发器，每次添加一个或多个联系人时都会收到一封电子邮件！

添加相关记录

触发器通常用于访问和管理与触发器上下文中的记录相关的记录 – 触发该触发器的记录。

如果没有机会与客户相关联，则此触发器为每个新的或更新的客户添加相关机会。触发器首先执行SOQL查询，以获取触发器触发的帐户的所有子机会。接下来，触发器遍历Trigger.New中的sObjects列表以获取每个帐户的sObject。如果该帐户没有任何相关的机会sObjects，for循环会创建一个。如果触发器创造了新的机会，最后的陈述将插入它们。

1. 使用开发者控制台添加以下触发器（按照HelloWorldTrigger示例的步骤，但使用AddRelatedRecord作为触发器名称）。

   trigger AddRelatedRecord on Account(after insert, after update) {
       List<Opportunity> oppList = new List<Opportunity>();
       
       // 获取这个触发器中客户的相关机会
       Map<Id,Account> acctsWithOpps = new Map<Id,Account>(
           [SELECT Id,(SELECT Id FROM Opportunities) FROM Account WHERE Id IN :Trigger.New]);
       
       // 为每个帐户添加一个机会，如果它还没有。
       // 遍历每个帐户。
       for(Account a : Trigger.New) {
           System.debug('acctsWithOpps.get(a.Id).Opportunities.size()=' + acctsWithOpps.get(a.Id).Opportunities.size());
           // 检查帐号是否有相关的机会。
           if (acctsWithOpps.get(a.Id).Opportunities.size() == 0) {
               // 如果没有，请添加一个默认机会
               oppList.add(new Opportunity(Name=a.Name + ' Opportunity',
                                          StageName='Prospecting',
                                          CloseDate=System.today().addMonths(1),
                                          AccountId=a.Id));
           }           
       }
   
       if (oppList.size() > 0) {
           insert oppList;
       }
   }

2. 要测试触发器，请在Salesforce用户界面中创建一个帐户，并将其命名为Apple和Orange。
3. 在客户页面的机会相关列表中，找到新的机会。触发器自动添加了这个机会！

使用触发器异常

您有时需要对某些数据库操作添加限制，例如在满足某些条件时防止保存记录。为了防止在触发器中保存记录，在有问题的sObject上调用addError（）方法。 addError（）方法在触发器中引发致命错误。错误消息显示在用户界面中并被记录。

如果具有相关机会，则以下触发器可防止删除帐户。默认情况下，删除一个帐户会导致所有相关记录的级联删除。这个触发器可以防止级联删除机会。为自己尝试这个触发器！如果你已经执行了前面的例子，你的组织有一个名为苹果和橙子的客户有一个相关的机会。本示例使用该示例帐户。

1. 使用开发者控制台添加以下触发器。

   trigger AccountDeletion on Account (before delete) {
      
       // 如果他们有相关的机会，防止删除帐户。
       for (Account a : [SELECT Id FROM Account
                        WHERE Id IN (SELECT AccountId FROM Opportunity) AND
                        Id IN :Trigger.old]) {
           Trigger.oldMap.get(a.Id).addError(
               '不能删除有相关机会的帐号');
       }
       
   }

2. 在Salesforce用户界面中，导航到Apples＆Oranges帐户的页面，然后单击 Delete.
3. 在确认弹出窗口中，单击 OK.

   使用自定义错误消息查找验证错误无法删除具有相关机会的帐户。

4. 禁用AccountDeletion触发器。如果你保持这个触发器激活，你不能检查你的挑战。
   1. 从设置中搜索Apex触发器。
   2. 在Apex触发器页面上，单击AccountDeletion触发器旁边的编辑。
   3. 取消选择 Is Active.
   4. 点击 Save.

触发器和外调

Apex允许您打电话并将Apex代码与外部Web服务集成。 Apex调用外部Web服务称为标注。例如，您可以调出股票报价服务以获取最新的报价。当从触发器中进行标注时，标注必须异步完成，以便在等待外部服务的响应时触发器不会阻止您的工作。异步标注在后台进程中进行，并在收到响应时外部服务返回它。

要从触发器中进行调用，请调用异步执行的类方法。这种方法被称为未来的方法，并用@future（callout = true）进行注释。此示例类包含制作标注的未来方法。

public class CalloutClass {
    @future(callout=true)
    public static void makeCallout() {
        HttpRequest request = new HttpRequest();
        // 设置端点URL。
        String endpoint = 'http://yourHost/yourService';
        request.setEndPoint(endpoint);
        // 将HTTP动词设置为GET。
        request.setMethod('GET');
        // 发送HTTP请求并获得响应。
        HttpResponse response = new HTTP().send(request);
    }
}

这个例子展示了调用类中的方法来异步调用标注的触发器。

trigger CalloutTrigger on Account (before insert, before update) {
    CalloutClass.makeCallout();
}